Pub_Balmora_Council
Morrowind.esm
Variables
5
Local Variables
rent
rentDay
rentMonth
setup
cleanup
Source
1begin Pub_Balmora_Council
2
3;Cell: Balmora, Council Club
4;Publican: Banor Seran
5;Flag: Rent_Balmora_Council
6
7;all rooms get rented for one day
8;This guy must be in the map where the room is if you use the locked door cell loading cleanup
9;rename the script for the guy and make a specific door to unlock or flag to set
10;NO actual key is given to player, a global flag is set that removes the ownership on the beds.
11
12;this script fires off when RENT is set true. Rent is set true throuhg the BEDS topic in dialogue, which all Publicans have.
13;Each publican will also have a separate response to buying the bed, so they can give simple directions. There is also a default one.
14
15short rent ;if room is rented, set through dialogue on this NPC
16short rentDay ;the day of the rental
17short rentMonth ;the month of the rental
18short setup ;if setup has been done
19short cleanup ;true if you want to cleanup all the flags, rental is over and can be reset
20;this script also uses a global variable (Rent_Bed_Pelagiad). Make a new one for each rental. You can have as many
21;beds as you want use that variable, it is used through the ownership data on the object reference
22
23if ( rent == 1)
24
25 if ( setup == 0 )
26 set rentDay to Day
27 set rentMonth to Month
28 set setup to 1
29 set Rent_Balmora_Council to 1 ;this is the flag for the ownership on the bed
30 "Rent_Balmora_Council_Door"->unlock ;also needed if you have locked the room, use a specific objectRef
31
32 else ;setup is done so check to see if the day is over
33
34 if ( Day != rentDay )
35 set cleanup to 1
36
37 elseif ( Month != rentMonth )
38 set cleanup to 1
39
40 endif
41
42 endif
43
44 if ( CellChanged == 1 ) ;this is only needed if you've done a locked door. If so, you only want to do this on cell change so you don't lock them in the room
45 if ( cleanup == 1 ) ;this gets called when the rental is over and everything can be cleaned up
46 set rent to 0
47 set Rent_Balmora_Council to 0
48 set setup to 0
49 set rentDay to 0
50 set rentMonth to 0
51 set cleanup to 0
52 "Rent_Balmora_Council_Door"->lock 50
53 endif
54 endif
55
56endif
57
58
59end Pub_Balmora_Council