jsaddhaScript
Morrowind.esm
Variables
4
Local Variables
noLore
followNow
distanceCheck
timer
Source
1Begin jsaddhaScript
2
3short noLore
4short followNow
5short distanceCheck
6float timer
7
8if ( MenuMode == 1 )
9 Return
10endif
11
12if ( GetJournalIndex HH_TwinLamps1 >= 70 )
13 Return
14endif
15
16if ( CellChanged == 1 )
17 if ( GetJournalIndex HH_TwinLamps1 > 0 )
18 if ( GetJournalIndex HH_TwinLamps1 < 100 )
19 Enable
20 Return
21 endif
22 endif
23 Disable
24 Return
25endif
26
27if ( GetHealth <= 0 )
28 return
29endif
30
31if ( GetCurrentAiPackage == 3 )
32;if follow is the current package, set followNow and continue...
33
34 set followNow to 1
35 SetHello 0
36
37 set "anes hlaren".followNow to 1
38 set "garyn girith".followNow to 1
39 set "sadal doren".followNow to 1
40
41 if ( GetAIPackageDone == 1 )
42 ;if follow is done, NPC has arrived...
43 Journal HH_TwinLamps1 70
44 set followNow to 0
45 set "anes hlaren".followNow to 0
46 set "garyn girith".followNow to 0
47 set "sadal doren".followNow to 0
48 AiFollow "galyn arvel" 0 0 0 0 0
49 Say "Vo\K\M\Flw_KM003.mp3" "Many thanks."
50 SetHello 30
51 endif
52
53 if ( timer > 3 )
54 if ( GetDistance "galyn arvel" < 300 )
55 ;if J'Saddha is near Galyn, end quest here as well if JSaddha can't reach his point
56 ;or if someone sets Galyn to a larger wander distance, etc.
57 Journal HH_TwinLamps1 70
58 set followNow to 0
59 set "anes hlaren".followNow to 0
60 set "garyn girith".followNow to 0
61 set "sadal doren".followNow to 0
62 AiFollow "galyn arvel" 0 0 0 0 0
63 Say "Vo\K\M\Flw_KM003.mp3" "Many thanks."
64 SetHello 30
65 endif
66 endif
67
68 if ( timer < 3 )
69 set timer to ( timer + GetSecondsPassed )
70 return
71 endif
72
73 if ( GetDistance Player < NPCVoiceDistance )
74 if ( GetDistance Player < 500 )
75 set distanceCheck to 0
76 endif
77 set timer to 0
78 return
79 endif
80
81 if ( distanceCheck == 0 )
82 Say "Vo\H\M\Flw_HM004.mp3" "Hey! Wait for me!"
83 set distanceCheck to 1
84 endif
85
86else
87 ;if follow is NOT the current package, make sure followNow is zero
88 set followNow to 0
89 set "anes hlaren".followNow to 0
90 set "garyn girith".followNow to 0
91 set "sadal doren".followNow to 0
92endif
93
94End